@echo off
title "Avira Nag Screen Removal"
rem http://www.mydigitallife.info/2009/11/13/remove-or-disable-avira-free-antivir-upgrade-to-premium-popup-ad-notifier-nag-screen-avnotify/
echo Avira Nag Screen Removal
echo ========================
echo.&echo NOTE: This program needs to be run with administrator privileges!
set avira_path=%ProgramFiles%\Avira\AntiVir Desktop
if "%PROCESSOR_ARCHITEW6432%"=="AMD64" set avira_path=%ProgramFiles(x86)%\Avira\AntiVir Desktop
if "%PROCESSOR_ARCHITECTURE%"=="AMD64" set avira_path=%ProgramFiles(x86)%\Avira\AntiVir Desktop
:_docheck
echo.&echo 1] Searching for Avira path...

if not exist "%avira_path%\avnotify.exe" goto _error
:_domagic
echo.&echo 2] Adding registry key: no splash screen on start-up (/nosplash)
reg add HKLM\Software\Microsoft\Windows\CurrentVersion\Run /v avgnt /d "\"%avira_path%\avgnt.exe\" /min /nosplash" /f

echo.&echo 3] Adding registry key: no advertisements on update (security policy)
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\Safer\CodeIdentifiers\0\Paths\{8ebd78aa-c67b-486a-b3ae-d84341d3cb70} /v Description /d "Avira Nag Screen Removal" /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\Safer\CodeIdentifiers\0\Paths\{8ebd78aa-c67b-486a-b3ae-d84341d3cb70} /v ItemData /d "%avira_path%\avnotify.exe" /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\Safer\CodeIdentifiers\0\Paths\{8ebd78aa-c67b-486a-b3ae-d84341d3cb70} /v SaferFlags /t REG_DWORD /d 0 /f
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\Safer\CodeIdentifiers\0\Paths\{8ebd78aa-c67b-486a-b3ae-d84341d3cb70} /v LastModified /t REG_QWORD /d 13228462993469524000 /f >nul
goto _end

:_error
echo.&echo ERROR! Could not find avnotify.exe in
echo        %avira_path%
set /p domagic=Do you want to continue assuming that the path above is correct? Y/N 
if /i "%domagic%"=="y" goto _domagic
echo.&echo Type in the path to the folder containing avnotify.exe
echo or abort by pressing [Enter]
set avira_path=NoGo
set /p avira_path=Path: 
if "%avira_path%"=="NoGo" goto _end
goto _docheck
:_end
echo.&pause